root/twttmixi/trunk/twttmixi.pl

#!/usr/bin/perl
$|++;

my $MYDIR;
BEGIN {
    $MYDIR = $0 =~ m!(.*[/\\])! ? $1 : './';
}

use lib "${MYDIR}lib";
use strict;
use warnings;
use Cache::File;
use LWP::UserAgent;
use XML::Simple qw( XMLin );
use Date::Parse;
use POSIX qw( strftime );
use Encode;
use WWW::Mixi;



### Account Setting
my $TWITTER_USERNAME    = 'pirolix';
my $MIXI_USERNAME       = 'your@mail.example.com';
my $MIXI_PASSWORD       = 'password';

### Title of mixi dialy
sub getEntryTitle {
    <<PERLHEREDOC;
[twitter] º£ÆEÎҁE­
PERLHEREDOC
}

### Header part of mixi diary body
sub getEntryBody {
    my $twits = shift;
    <<PERLHEREDOC;
$twits
---
Powered by twitter (http://twitter.com/$TWITTER_USERNAME) + twttmixi
PERLHEREDOC
}

### Format a twit
sub getFormattedTwit {
    my $twit = shift;
    <<PERLHEREDOC;
$twit->{created_at_formatted}¢§$twit->{text_sjis}
PERLHEREDOC
}

### Format timestamp of a twit
sub getFormattedDatetime {
    strftime '%H:%M', localtime( $_[0] );
}



### Other definition
my $NET_TIMEOUT         = 30;
my $TWITTER_API         = "http://twitter.com/statuses/user_timeline/$TWITTER_USERNAME.xml";
my $CACHE_FILENAME      = "${MYDIR}.cache";

### Print message
sub msg {
    print STDOUT @_, "\n";
}

### Cache::File
my $cache = undef;
my $CACHE_KEY_NAME = 'last_update';
sub initCache {
    $cache = Cache::File->new( cache_root => $CACHE_FILENAME )
        or die 'Failed to initialize <Cache::File>';
}

### Twitter
sub getTwitter {
    msg( "* Retrieving your twits from twitter.com" );
    my $twitter = LWP::UserAgent->new
        or die 'Failed to initialize <LWP::UserAgent>';
    $twitter->timeout( $NET_TIMEOUT );
    msg( "\tConnecting twitter.com" );
    my $res = $twitter->get( $TWITTER_API )
        or die 'Failed to retrieve - '. $TWITTER_API;
    $res->is_success
        or die $res->status_line;
    my $content = $res->content
        or die $res->status_line;
    my $ref = XMLin( $content )
        or die 'Failed to handle XML response';
    msg( "\tdone" );
    $ref;
}

### mixi
sub postTwits2mixi {
    my $twits = shift;
    msg( "* Post your twits into mixi" );
    my $mixi = WWW::Mixi->new( $MIXI_USERNAME, $MIXI_PASSWORD );
    $mixi->timeout( $NET_TIMEOUT );
    msg( "\tLogin" );
    my $res = $mixi->login
        or die;
    msg( "\tFirst posting a dialy" );
    my @items = $mixi->get_add_diary_preview(
            diary_title => 'dmy',
            diary_body => 'dmy',
    ) or die;
    msg( "\tConfirm posting the dialy" );
    $mixi->get_add_diary_confirm(
            diary_title => getEntryTitle(),
            diary_body => getEntryBody( $twits ),
            post_key => $items[0]->{post_key},
    );
    msg( "\tdone" );
}

### Main
sub main {
    msg( "* twttmixi - TWiTter To MIXI dialy");

    initCache();

    my $this_update = 0;
    my $last_update = $cache->get( $CACHE_KEY_NAME ) || 0;
    msg( "\tLast proceeded at ". getFormattedDatetime( $last_update ));

    my $ref = getTwitter();

    my $statuses = $ref->{status};
    my $twits = '';
    foreach (sort keys %$statuses) {
        my $item = $statuses->{$_}
            or next;
        my $t = str2time( $item->{created_at} );
        $t <= $last_update
            and next;
        $this_update <= $t
            and $this_update = $t;
        $item->{created_at_formatted} = getFormattedDatetime( $t );
        $item->{text_sjis} = encode ('eucjp', $item->{text});
        $twits .= getFormattedTwit( $item );
    }

    unless( $this_update ) {
        msg( "* Not found new twits since last proceeded" );
        return;
    }

    postTwits2mixi( $twits );

    $cache->set( $CACHE_KEY_NAME, $this_update ); 
}
&main();

__END__
WWW::Mixi €ÎºÇ¿·ÈǀϰʲŒ€Î URL €ÇÆþŒê€·€Æ€¯€À€µ€€
http://digit.que.ne.jp/work/wiki.cgi?mycmd=search&mymsg=Perl%e3%83%a2%e3%82%b8%e3%83%a5%e3%83%bc%e3%83%ab%2fWWW%3a%3aMixi